Next: , Previous: key, Up: set-show


2.19.29 label

Arbitrary labels can be placed on the plot using the label command.

Syntax:

           set label {<tag>}
                     { {"<label text>"{,<value>}} {, ...}} }
                     {at <position>}
                     {left | center | right}
                     {norotate | rotate {by <degrees>}}
                     {font "<name>{,<size>}"}
                     {front | back}
                     {textcolor <colorspec>}
                     {point <pointstyle> {offset x, y} | nopoint}
           unset label {<tag>}
           show label
     

The <position> is specified by either x,y or x,y,z, and may be preceded by `first`, `second`, `graph`, or `screen` to select the coordinate system. See `coordinates` for details.

The tag is an integer that is used to identify the label. If no <tag> is given, the lowest unused tag value is assigned automatically. The tag can be used to delete or modify a specific label. To change any attribute of an existing label, use the label command with the appropriate tag, and specify the parts of the label to be changed.

The <label text> can optionally contain numbers, generated by replacement of printf()-like format specifiers contained in <label text>. The number to be used is given by the <value> following the text. The same formatting capabilities as for tic labels are available. See the help on `format specifiers` for details. To display more than one distinct <value> with a single label, several pairs of <label text> and <value> may be given. Note that <value> is treated as a constant expression, i.e. if it contains variables, the label text will not change if the variable values are modified, later on. The decimalsign option, if active, overrides the decimal separator character of numbers entered into label texts.

By default, the text is placed flush left against the point x,y,z. To adjust the way the label is positioned with respect to the point x,y,z, add the justification parameter, which may be `left`, `right` or `center`, indicating that the point is to be at the left, right or center of the text. Labels outside the plotted boundaries are permitted but may interfere with axis labels or other text.

If `rotate` is given, the label is written vertically (if the terminal can do so, of course). If `rotate by <degrees>` is given, conforming terminals will try to write the text at the specified angle; non-conforming terminals will treat this as vertical text.

Font and its size can be chosen explicitly by `font "<name>{,<size>}"` if the terminal supports font settings. Otherwise the default font of the terminal will be used.

If `front` is given, the label is written on top of the graphed data. If `back` is given (the default), the label is written underneath the graphed data. Using `front` will prevent a label from being obscured by dense data.

`Textcolor <colorspec>` changes the color of the label text. `<colorspec>` is either a linetype or a mapping onto the pm3d color palette (available only in `splot`), see help for palette.

        `textcolor` may be abbreviated `tc`.
        `tc default` resets the text color to its default state.
        `tc lt <n>` sets the text color to that of line type <n>.
        `tc palette z` selects a palette color corresponding to the label z position.
        `tc palette cb <val>` selects a color corresponding to <val> on the colorbar.
        `tc palette fraction <val>`, with 0<=val<=1, selects a color corresponding to
            the mapping [0:1] to grays/colors of the palette.
     

If a <pointstyle> is given, using keywords `lt`, `pt` and `ps`, see style, a point with the given style and color of the given line type is plotted at the label position and the text of the label is displaced slightly. The displacement defaults to 1, 1 in pointsize units and can be controlled by the optional `offset x, y`. Example: `offset 2, -3` would displace the labels 2 * pointsize horizontally and -3 * pointsize vertically from the actual coordinate point as given by `position`. The size of the point depends also on the setting of pointsize. This option is used by default for placing labels in `mouse` enhanced terminals. Use `nopoint` to turn off the drawing of a point near the label (this is the default).

If one (or more) axis is timeseries, the appropriate coordinate should be given as a quoted time string according to the timefmt format string. See xdata and timefmt.

The EEPIC, Imagen, LaTeX, and TPIC drivers allow \\ in a string to specify a newline.

Examples:

To set a label at (1,2) to "y=x", use:

           set label "y=x" at 1,2
     

To set a Sigma of size 24, from the Symbol font set, at the center of the graph, use:

           set label "S" at graph 0.5,0.5 center font "Symbol,24"
     

To set a label "y=x^2" with the right of the text at (2,3,4), and tag the label as number 3, use:

           set label 3 "y=x^2" at 2,3,4 right
     

To change the preceding label to center justification, use:

           set label 3 center
     

To delete label number 2, use:

           unset label 2
     

To delete all labels, use:

           unset label
     

To show all labels (in tag order), use:

           show label
     

To set a label on a graph with a timeseries on the x axis, use, for example:

           set timefmt "%d/%m/%y,%H:%M"
           set label "Harvest" at "25/8/93",1
     

To display a freshly fitted parameter on the plot with the data and the fitted function, do this after the `fit`, but before the `plot`:

           set label 'a = %3.5g',par_a     at 30, 15
           set label 'b = %s*10^%S',par_b  at 30, 20
     

To set a label displaced a little bit from a small point:

           set label 'origin' at 0,0 point lt 1 pt 2 ps 3 offset 1,-1
     

To set a label whose color matches the z value (in this case 5.5) of some point on a 3D splot colored using pm3d:

           set label 'text' at 0,0,5.5 tc palette z